From 1eb69e9a795cc19450178c07d8d382622bc7ad70 Mon Sep 17 00:00:00 2001
From: Pedro Pereira <pedro.hr.pereira@proton.me>
Date: Fri, 16 Oct 2026 15:19:13 -0300
Subject: first commit

---
 .config/zsh/oh-my-zsh/plugins/multipass/_multipass | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 .config/zsh/oh-my-zsh/plugins/multipass/_multipass

(limited to '.config/zsh/oh-my-zsh/plugins/multipass/_multipass')

diff --git a/.config/zsh/oh-my-zsh/plugins/multipass/_multipass b/.config/zsh/oh-my-zsh/plugins/multipass/_multipass
new file mode 100644
index 0000000..c742df6
--- /dev/null
+++ b/.config/zsh/oh-my-zsh/plugins/multipass/_multipass
@@ -0,0 +1,73 @@
+#compdef multipass
+
+_multipass_get_command_list () {
+  # Sample output:
+  # $ multipass --help
+  # ...
+  # Options:
+  #   -h, --help     Display this help
+  #   -v, --verbose  Increase logging verbosity. Repeat the 'v' in the short option
+  #                  for more detail. Maximum verbosity is obtained with 4 (or more)
+  #                  v's, i.e. -vvvv.
+  # ...
+  # Available commands:
+  #   alias     Create an alias
+  #   aliases   List available aliases
+  #   ...
+  #
+  $_comp_command1 --help | sed '1,/Available commands/d' | awk '/^[ \t]*[a-z]+/ { print $1 }'
+}
+
+_multipass_get_args_list () {
+  # Sample output:
+  # $ multpass help stop
+  # ...
+  # Options:
+  # -h, --help         Display this help
+  # -v, --verbose      Increase logging verbosity. Repeat the 'v' in the short
+  #                     option for more detail. Maximum verbosity is obtained with
+  #                     4 (or more) v's, i.e. -vvvv.
+  # --all              Stop all instances
+  # -t, --time <time>  Time from now, in minutes, to delay shutdown of the
+  #                     instance
+  # -c, --cancel       Cancel a pending delayed shutdown
+  #
+  # Arguments:
+  # name               Names of instances to stop. If omitted, and without the
+  #                     --all option, 'primary' will be assumed.
+  #
+  local arg_name=$($_comp_command1 help ${words[2]} | sed '1,/Arguments/d' | awk '/^[ \t]*[a-z]+/ { print $1; exit }')
+
+  case $arg_name in
+    name)
+      # Sample output:
+      # $ multipass list
+      # Name                    State             IPv4             Image
+      # workable-poacher        Running           10.2.0.28        Ubuntu openHAB Home Appliance
+      #
+      $_comp_command1 list | sed '1d' | awk '/^[ \t]*[^ ]+/ { print $1 }'
+    ;;
+    command)
+      _multipass_get_command_list
+    ;;
+  esac
+}
+
+_multipass () {
+  typeset -A opt_args
+
+  _arguments \
+    '1: :->command'\
+    '*: :->args'
+
+  case $state in
+    command)
+      compadd $(_multipass_get_command_list)
+    ;;
+    *)
+      compadd $(_multipass_get_args_list)
+    ;;
+  esac
+}
+
+_multipass "$@"
-- 
cgit v1.3